Calculo del decaimiento H->γγ

A. I. Hernández-Juárez
alan.hernandezjua@alumno.buap.mx

Este notebook presenta una manera sencilla y práctica para aprender a hacer cálculos a un lazo. Se espera que el usuario sea capaz de rehacer el código para que funcione de mejor manera.

Este notebook está inspirado en las clases del Dr. Gilberto Tavares Velasco en el posgrado de física de la FCFM-BUAP durante los años 2016 -2019.

Comandos sus opciones se pueden encontrar en los manuales correspondientes.

FeynArts y FeynCalc: generación de la amplitud

FeynArts ya viene pre-cargado en FeynCalc. Simplemente hay que llamarlo cuando usamos Feyncalc

Cargamos las paqueterias

Se carga FeynArts

$LoadAddOns={"FeynArts"};

Se carga FeynCalc

<<FeynCalc`

Generación de diagramas de Feynman: FeynArts

CreateTopologies[L,i->j] sirve para indicar el tipo de topologías que queremos, L es el número de loops, i partículas iniciales, j partículas finales.

Generamos las topologías

topo=CreateTopologies[(*número lazos*),->(*partículas iniciales-finales*)];

El siguiente comando le indica a FeynArts que puede llamar modelos adicionales al SM

FAPatch[PatchModelsOnly->True]

InsertFields - generamos los diagramas permitidos por las topologías del modelo.

Las partículas de nuestro proceso en el lenguaje de FeynArts son:
S[1] - Higgs,
V[1] - Fotón

InsertionLevel el nivel de partículas que se van a considerar (ver manual).

Diagramas1=InsertFields[topo(*indica la topología*),S[1]->{V[1],V[1]}(*partículas iniciales -> partículas finales*),InsertionLevel->{Particles}];

Paint dibuja los diagramas posibles en la topología indicada con las partículas iniciales y finales dadas.

Paint[Diagramas1]

Note que aparecen diagramas extra a los discutidos: FeynArts no da la norma unitaria por default.

Norma unitaria

Model indica el modelo que se va a usar (por default considera el Modelo Estándar).
GenericModel las estructuras de Lorentz del modelo.

Uni=InsertFields[topo,S[1]->{V[1],V[1]},InsertionLevel->{Particles},GenericModel->{"Lorentz","UnitaryLorentz"},Model-> {"SM","UnitarySM"}];

Paint[Uni]

Note que parece haber diagramas extra: Topologicamente no son iguales, por tanto se deben de considerar.

Creamos la amplitud en FeynArts

Con CreateFeynAmp creamos una lista con las amplitudes de los diagramas de Feynman en notación de FeynArts.

amps1=CreateFeynAmp[Uni (*Diagramas de los cuales se va a crear la amplitud*),PreFactor->1 (*FeynArts agrega cosntantes extra las cuales pueden ser removidas*),GaugeRules->{FAGaugeXi[W|Z]->}(*el valor que va a tomar la norma de gauge: para la norma unitaría ϵ tiende a infinito *)];

Amplitud con FeynCalc

Convirtamos las amplitudes generadas por FeynArts a código de FeynCalc

Definimos algunas sustituciones convenientes:

sust={FCGV[s_]:>ToExpression[s],Pair[LorentzIndex[μ, D], 
  Momentum[Polarization[p1, 
    -I, Transversality -> 
     True], D]]->1,Pair[LorentzIndex[ν, D],  Momentum[Polarization[p2, 
    -I, Transversality -> 
     True], D]]->1};

{EL=g SW,cw=CW,sw=SW}

FCampTree nos da las amplitudes definidas anteriromente en notación de FeynCalc.
IncomingMomenta y OutgoingMomenta define los momentos entrantes y salientes.
ChangeDimension la dimensión en la que define la amplitud.
Otras opciones las pueden cambiar ustedes mismos para ver la diferencia entre True y False.

ampfc1=FCFAConvert[amps1,IncomingMomenta->{q},OutgoingMomenta->{p1,p2},TransversePolarizationVectors-> {p1,p2},UndoChiralSplittings-> True,DropSumOver->True,LoopMomenta->{k},LorentzIndexNames->{μ,ν},ChangeDimension->D]/.sust;

Condiciones de capa de masa

Es conveniente definir las condiciones de capa de masa

q=p1+p2;

{ScalarProduct[p1,p1]=0,ScalarProduct[p2,p2]=0,ScalarProduct[p1,p2]=(mh^2)/2};

condiciones de transversalidad

{Pair[LorentzIndex[μ],Momentum[p1]]=0,Pair[LorentzIndex[ν],Momentum[p2]]=0};

Diagrama con fermiones en el lazo

Vamos a considerar solo el caso del quark top, corresponde a los diagramas 9 y 12

amp1=ampfc1[[9]];

amp2=ampfc1[[12]];

La amplitud total de estos dos diagramas es:

ampF=amp1+amp2;

DiracSimplify calcula las trazas

ampF2=ampF//DiracSimplify;

TID aplica el método de Passarino-Veltman a la amplitud.
Se debe multiplicar por ((I/((4π)^2( I π^2)))), ver manual

ampF3=((I/((4π)^2( I π^2))))TID[ampF2(*amplitud*),k(*momento indeterminado*),ToPaVe->True(*reducir el resultadoa funciones escalares*),PaVeLimitTo4->True (*pasar de D a 4 dimensiones*)]//Simplify

Vea que la amplitud tiene la estructura esperada

Diagramas con bosones W en el lazo

ampW1=ampfc1[[19]]//FCE;

ampW2=ampfc1[[20]]//FCE;

ampW3=ampfc1[[21]]//FCE;

ampWs=ampW1+ampW2+ampW3;

ampWF=((I/((4π)^2( I π^2))))TID[ampWs,k,ToPaVe->True,PaVeLimitTo4->True ]//Simplify

Note que de nueva cuenta se tiene la estructura esperada.

Quit[]

Evaluación de las funciones de Passarino-Veltman

Llamamos a LoopTools

SetDirectory["/home/usuario/HEPtools/LoopTools-2.16/build"];
Install["LoopTools"]

Factor de forma contribución quark top en el lazo

topC=(1/(18 (mh^2) MW (π^2)))I (g^3) (MT^2) (SW^2) (-2+((mh^2)-4 (MT^2)) PaVe[0,{0,0,(mh^2)},{(MT^2),(MT^2),(MT^2)}])/.{mh->125.25,MT->172.69,g->.653,MW->80.419,SW->Sqrt[.231]}

Factor de forma contribución bosón W en el lazo

Wcon=-(1/(16 (mh^2) MW (π^2)))I (g^3) (SW^2) (-(mh^2)-6 (MW^2)+6 (MW^2) ((mh^2)-2 (MW^2)) PaVe[0,{0,0,(mh^2)},{(MW^2),(MW^2),(MW^2)}])/.{mh->125.25,MT->172.69,g->.653,MW->80.419,SW->Sqrt[.231]}

Quit[]

Branching ratio H->γγ

<<FeynCalc`

Cuadramos la amplitud

Volvemos a definir nuestras condiciones de capa de masa

q=p1+p2;

{ScalarProduct[p1,p1]=0,ScalarProduct[p2,p2]=0,ScalarProduct[p1,p2]=(mh^2)/2};

Hay que considerar los vectores de polarización.
No olvide multiplicar por un factor de 3 (debido a la carga de color) la contribución del top.

ampF=(-2 FV[p1,ν] FV[p2,μ]+(mh^2) MT[μ,ν]) ComplexConjugate[PolarizationVector[p1,μ]]ComplexConjugate[PolarizationVector[p2,ν]]

Cuadramos

ampF2=ampF ComplexConjugate[ampF]//Calc

Aplicamos la suma sobre polarizaciones. 
Se debe aplicar dos veces porque tenemos dos fotones.

ampF3=DoPolarizationSums[ampF2(*amplitud*),p1(*momento*),0(*masa del bosón de gauge*)]//Simplify

ampF4=DoPolarizationSums[ampF3,p2,0]

ampF4/.{mh->125.25}

Branching ratio

Usamos la formula vista

Br=(1/(32 π mh (.0041)))ampF4/.{mh->125.25}

Tarea

1)Probar que las contribuciones de los fermiones restantes son despreciables en comparación con la del quark top.
2)Probar que sin usar la norma unitaria el resultado final es el mismo. Es decir, calcule todos los diagramas que que dibujamos al inicio (menos los correspondientes a los fermiones) y compare con la contribución con solo bosones W en el lazo en la norma unitaria.